Buscar usuario

Pessoal, o exemplo abaixo peguei  no forum , o mesmo pega o usuario logado em um banco access: agora como faço funcionar substituindo o ListView  e ImageList por um ListBox? Preciso usar sem esse componentes.

' Muestra los usuarios conectados una base de datos de Microsoft Access
' ---------------------------------------------------------------------
' Rubén Vigón
' Microsoft MVP Visual Basic
' vigon@mvps.org

Option Explicit
Private Const JET_SCHEMA_USERROSTER As String = "{947bb102-5d43-11d1-bdbf-00c04fb92675}"

Private Sub MostrarConexiones(ByVal strRutaMDB As String)
Dim Cn As ADODB.Connection, Rs As ADODB.Recordset
    ListView1.ListItems.Clear
    Set Cn = New ADODB.Connection
    Set Rs = New ADODB.Recordset
    Cn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strRutaMDB & ";Persist Security Info=False"
    Set Rs = Cn.OpenSchema(adSchemaProviderSpecific, , JET_SCHEMA_USERROSTER)
    While Not Rs.EOF
        With ListView1.ListItems.Add(, , Rs!COMPUTER_NAME, , 3)
            .SubItems(1) = Rs!LOGIN_NAME
            .SubItems(2) = Rs!CONNECTED
        End With
        Rs.MoveNext
    Wend
    Rs.Close
    Cn.Close
    Set Rs = Nothing
    Set Cn = Nothing
End Sub

Private Sub Form_Load()
    If Len(Command$) Then
        If Len(Dir(Command$)) Then
            Screen.MousePointer = vbHourglass
            MostrarConexiones Command$
            StatusBar1.SimpleText = Command$
            mnuVerActualizar.Enabled = True
            Toolbar1.Buttons("act").Enabled = True
            Screen.MousePointer = vbDefault
        End If
    End If
End Sub

Private Sub Form_Resize()
    If WindowState <> vbMinimized Then _
        ListView1.Move 0, 450, ScaleWidth, ScaleHeight - 750
End Sub

Private Sub mnuArchivoAbrir_Click()
    With CommonDialog1
        .Filter = "Bases de datos (*.mdb)|*.mdb|Todos los archivos (*.*)|*.*"
        .InitDir = App.Path
        .Flags = cdlOFNFileMustExist
        .ShowOpen
        If Len(.FileName) Then
            Screen.MousePointer = vbHourglass
            MostrarConexiones .FileName
            Caption = "Usuarios conectados: " & .FileTitle
            StatusBar1.SimpleText = .FileName
            mnuVerActualizar.Enabled = True
            Toolbar1.Buttons("act").Enabled = True
            Screen.MousePointer = vbDefault
        End If
    End With
End Sub

Private Sub mnuVerActualizar_Click()
    Screen.MousePointer = vbArrowHourglass
    MostrarConexiones StatusBar1.SimpleText
    Screen.MousePointer = vbDefault
End Sub

Private Sub Toolbar1_ButtonClick(ByVal Button As MSComctlLib.Button)
    Select Case Button.Key
        Case "abr"
            mnuArchivoAbrir_Click
        Case "act"
            mnuVerActualizar_Click
    End Select
End Sub