Tela de Login

este é código de uma tela de login que eu tenho (tem dois textbox (usuario e senha) um botão para confirmar e outro para cancelar):

'Desenvolvedor......: André Martini
'Data de criação....: 18/05/2005
'Funcionalidade.....: Este é o formulário de controle de login do sistema
'Referências de uso.: mdiPrincipal
'Exemplo de uso.....: sem exemplo
'Destacar alterações:

Option Explicit 'requer que todas as variáveis sejam declaradas
DefInt A-Z 'variáveis inteiras, por default

Dim intNumTent As Integer 'numero de tentativas de login (máximo três)

'Desenvolvedor......: André Martini
'Data de criação....: 25/05/2005
'Funcionalidade.....: esta sub trata a ação do click no botão Cancela
'Referências de uso.: frmLogin
'Exemplo de uso.....: cmdCancela_Click
'Destacar alterações:
Private Sub cmdCancela_Click()
strPWUsuario$ = ""         'inicializa variáveis publicas - Nome do usuário e
strPWSenha$ = ""           'senha
txtUsuario.Text = ""       'inicializa também os dois campos onde serão
txtSenha.Text = ""         'digitadas as informações iniciais
Unload Me                  'descarrega este form
End Sub

'Desenvolvedor......: André Martini
'Data de criação....: 25/05/2005
'Funcionalidade.....: esta sub trata a ação do click no botão Confirma
'Referências de uso.: frmLogin
'Exemplo de uso.....: cmdConfirma_Click
'Destacar alterações:
Private Sub cmdConfirma_Click()
On Error Resume Next
Screen.MousePointer = vbHourglass
Dim intPareceOk As Integer 'controle se foi preenchido os campos de usuário e senha
intPareceOk = (Len(txtUsuario.Text) > 0 And Len(txtSenha.Text) > 0)                                    'parece ok se os dois campos têm valores...
If Not intPareceOk Then                          'se não parece ok,
    Screen.MousePointer = vbNormal
    Beep                                           'apita e mostra mensagem de erro...
    MsgBox "Favor digitar a informação solicitada!", vbExclamation, strAtencao$
    txtUsuario.SetFocus                           'coloca o foco no campo nome do usuário
Else 'parece que está tudo OK - vamos ver...
    'conexão com banco de dados
    Cnn.ConnectionString = "driver={SQL Server};server=AresDesenv;uid=" & Trim(txtUsuario.Text) & ";pwd=" & Trim(txtSenha.Text) & ";database=SIGA_6Horas"
    'Cnn.ConnectionString = "driver={SQL Server};server=ZEUS;uid=" & Trim(txtUsuario.Text) & ";pwd=" & Trim(txtSenha.Text) & ";database=MICROSIGA"
    Cnn.CommandTimeout = 0
    Cnn.Open
    'se ocorreu algum erro
    If Err <> 0 Then
      'verifica o número de tentativas
      If intNumTent < 3 Then            'se ainda não tentou 3 vezes,
        Screen.MousePointer = vbNormal
        Beep                            'apita e
        MsgBox "Nome do usuário e/ou senha inválida!", vbCritical, strAtencao$ 'avisa que deu erro...
        txtUsuario.SetFocus             'volta o foco para o campo nome do usuário
        intNumTent = intNumTent + 1     'tentou mais uma vez
        Exit Sub
      End If
    Else
      Screen.MousePointer = vbNormal
      'carrega variáveis e abre formulario principal
      strPWUsuario$ = txtUsuario.Text                           'variáveis da senha deixa normal
      strPWSenha$ = txtSenha.Text                             'usar em mensagens
      mdiPrincipal.Show
    End If
    Unload Me 'descarrega este form
End If
End Sub

'Desenvolvedor......: André Martini
'Data de criação....: 25/05/2005
'Funcionalidade.....: esta sub trata a ação do KeyPress do formulário
'Referências de uso.: frmLogin
'Exemplo de uso.....: Form_KeyPress()
'Destacar alterações:
Private Sub Form_KeyPress(KeyAscii As Integer)
If KeyAscii = vbKeyEscape Then 'se teclou ESC
Unload Me 'tira este form da memória
End If
End Sub

'Desenvolvedor......: André Martini
'Data de criação....: 25/05/2005
'Funcionalidade.....: esta sub trata a ação load do formulário
'Referências de uso.: frmLogin
'Exemplo de uso.....:
'Destacar alterações:
Private Sub Form_Load()
subMain
Me.Caption = strNomeSistema$ + Chr$(160)               'seu título é o nome do sistema
Me.Icon = LoadResPicture(10, vbResIcon)                'carrega icone do sistema
Top = Screen.Height / 2                                'centraliza vertical e
Left = Screen.Width / 2                                'horizontalmente
Set cmdConfirma.Picture = LoadResPicture(13, vbResIcon) 'carrega figura do botão ok
Set cmdCancela.Picture = LoadResPicture(2, vbResIcon) 'carrega figura do botão cancela
Set picChave.Picture = LoadResPicture(12, vbResIcon)    'carrega figura da picturebox
End Sub

'Desenvolvedor......: André Martini
'Data de criação....: 25/05/2005
'Funcionalidade.....: esta sub trata a ação do KeyPress do campo senha
'Referências de uso.: frmLogin
'Exemplo de uso.....: txtSenha_KeyPress
'Destacar alterações:
Private Sub txtSenha_KeyPress(KeyAscii As Integer)
If KeyAscii = vbKeyReturn Then                       'se for um ENTER,
    KeyAscii = 0                                       'anula o ENTER
    On Error Resume Next                               'evita erro
    cmdConfirma.SetFocus                               'foco no botao Ok
End If
End Sub

'Desenvolvedor......: André Martini
'Data de criação....: 25/05/2005
'Funcionalidade.....: esta sub trata a ação do KeyPress do campo usuário
'Referências de uso.: frmLogin
'Exemplo de uso.....: txtUsuario_KeyPress
'Destacar alterações:
Private Sub txtUsuario_KeyPress(KeyAscii As Integer)
If KeyAscii = vbKeyReturn Then                       'se for um ENTER,
    KeyAscii = 0                                       'anula o ENTER
    On Error Resume Next                               'evita erro
    txtSenha.SetFocus                                  'foco no campo senha
End If
End Sub